変更を記録する (値変更時にセルにメモを付与する)

値を変更すると、そのセルにメモ（コメント）を付与するマクロです。変更履歴機能と似ていますが、このマクロは履歴ではなく変更の有無を確認することを目的としています。

元の値に戻すとメモは削除されて「変更なし」状態になります
（変更履歴機能では2度の変更として記録されるところです）

「反映」により履歴がクリアされることはありません

変更と同時にメモが付与されるので、確認しながら作業を進めるのに便利です

イベントプロシージャでメモを付与するマクロ

Option Explicit
Dim VAL As Variant

'============================
Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    
    On Error GoTo ENDUP
    If Intersect(Target, Range("変更管理")) Is Nothing Then Exit Sub
    If Target.Cells.Count <> 1 Then Exit Sub
    
    VAL = Target.Value

ENDUP:
End Sub

'============================
Private Sub Worksheet_Change(ByVal Target As Range)

    Dim comVal As Variant 'メモテキスト
    
    On Error Resume Next
    If Intersect(Target, Range("変更管理")) Is Nothing Then Exit Sub
    If Target.Cells.Count <> 1 Then Exit Sub
    
    With Target
        comVal = .Comment.Text
        If IsEmpty(comVal) Then
            'メモなし & 値が変化 → メモ作成
            If .Value <> VAL Then .AddComment CStr(VAL)
        Else
            'メモあり & 値がメモと同じ → メモ削除
            If CStr(.Value) = comVal Then .Comment.Delete
        End If
    End With
    
End Sub